Essi', ammettiamolo, ci mancavano un po' di esempiuzzi cazzuti di quelli che quando li guardi dici "azzo che esempio cazzuto!".
O no? Essi'. No! HO DETTO DI SI! Ah, ok :o*
Ecco a voi una listozza patcharozza cazzuta.
Spero vi aiutino nell'apprendere il coding ed il mIRCing scripting che tutti noi coder mIRCscriptatori amiamo come se fosse una bella fanciulla che ce la da con passione scambiandoci per Keanu Reeve (w le ragazze miopi).

Ricordo che per poter tenere sotto controllo iss site, potete piazzarvi il seguente script int'u scripte vostro :o*


Check Update HoT - by Lamerone Burp

Ed ecco che la realta' diventa sogno e che il sogno diventa niente.
Fika st'introduzione, eh? :o*******
Prendendo spunto da un'idea di Vm18 mi sono detto: hai gli strumenti per rendere possibile cio' che vuoi fare, hai i frequentatori abituali del sito, hai le palle per andare in Vietnam e tornare con il ricordo di una mitragliata sparata dall'ultimo Viet persosi nel bosco che ancora crede di stare in guerra, hai la mamma, hai un cane che ti sta mordendo i testicoli, una tanica di kerosene e una di napalm... che altro ti serve? Mi servirebbe uno script da passare agli abituali del sito in modo che, stando su IRC, possano sempre controllare gli eventuali aggiornamenti.
E cosi' il pensiero si trasformo in idea e l'idea in mascarpone.
E lo scarpone me lo tirate voi se non arrivo al dunque.
Ok ok ok ok ok ok ok ok ok ok ok ok ok ok ok ok ok ok.
Per tutti coloro i quali fossero interessati, ora possono piazzarsi uno script molto semplice e breve all'interno del loro mIRC.
Lo script in questione serve a fare un check degli aggiornamenti del sito che si presenta in questo momento davanti agli okkiettini da cerbiatto che avete.
Come fare ad "installarlo"??
Semplice.
Aprite il vostro mIRC e premete ALT + R.
Incollate lo script che trovate qui di seguito alla fine di una delle tante finestre (okkio a non fare cazzate ed ad incollarlo in mezzo ad una routine loop e end).
Premete il pulsantino dell'amore, leggasi "OK".
Premete ALT + O.
Andate nella sessione IRC e Perform.
Scriveteci chkupd e attivate la casellina di spunta.
Date OK e scrivete in una qualsiasi finestra del mIRC
/perform
Se lo script vi dice
* Perform is ON
allora e' tutto pronto per il collaudo.
In caso contrario ripetete tutto da 0.
Se non riuscite a districarvi, mailatemi e vi guidero passo passo.

Lo script...

alias chkupd { sockopen lamesite 195.210.93.179 80 }
on *:sockopen:lamesite: {
 if ($sockerr) return
 sockwrite -n $sockname GET /lamerone/lastupdate.txt
 }
 on *:sockread:lamesite: {
  if ($sockerr > 0) return
  sockread %lamezzn.dati
  if (??/??/???? iswm %lamezzn.dati ) {
  if (%lamezzn.locale == %lamezzn.dati) {
  unset %lamezzn.dati | sockclose lamesite | halt
  }
  set %lamezzn.locale %lamezzn.dati
  window -c @Update_ZZN
  window -axkb @Update_ZZN Arial 10
  }
 :loop
 sockread %lamezzn.dati
 if (%lamezzn.dati == $null) { sockclose lamesite | halt }
 else { aline @Update_ZZN %lamezzn.dati }
 goto loop
}

Et voilat.
Il gioco e' fatto.
Buon Autoupdate a tutti e non mi mailate dicendo che non siete riusciti ad installarlo su IRCle!


Mass Deop

Uno scriptino molto semplice: il suo scopo e' quello di fare un massdeop in un canale (ossia un deop di massa dei vari op... che genio).
La sua utilita' e' dubbia... difficile che riusciate a concludere l'operazione con successo, specialmente se il numero degli op del canale e' alto.
La sintassi e': /massdeop [#canale]
Se scrivete solo /massdeop, lo script effettuera' l'operazione nel canale corrente, se specificate il nome del canale...

alias massdeop {
 if ($1 == $null) { .massdeop $active | halt }
 if ($1 !ischan) { echo -a Immettere un nome di canale valido... | halt }
 if ($me !isop $1) { echo -a Non sei oppato su $1... | halt }
 echo -a MassDeop su $1 $+ ... In corso...
 :loop
 inc %massdeop.cnt
 set %massdeop.nick $nick($1,%massdeop.cnt,o)
 if (%massdeop.nick == $null) {
  if (%massdeop.nicks != $null) { .mode $1 -ooo %massdeop.nicks }
  unset %massdeop.*
  halt
 }
 if (%massdeop.nick == $me) { goto loop }
 set %massdeop.nicks %massdeop.nicks %massdeop.nick
 if ($numtok(%massdeop.nicks,32) == 3) && ($me isop $1) {
 .mode $1 -ooo %massdeop.nicks | unset %massdeop.nicks | goto loop }
 goto loop
}


Mass Op

Anche questo e' uno scriptino molto molto semplice: il suo scopo e' quello di fare un massop in un canale (ossia un op di massa dei vari normal users...).
La sintassi e': /massop [#canale]
Se scrivete solo /massop, lo script effettuera' l'operazione nel canale corrente, se specificate il nome del canale...

alias massop {
 if ($1 == $null) { .massop $active | halt }
 if ($1 !ischan) { echo -a Immettere un nome di canale valido... | halt }
 if ($me !isop $1) { echo -a Non sei oppato su $1... | halt }
 echo -a MassOp su $1 $+ ... In corso...
 :loop
 inc %massop.cnt
 set %massop.nick $nick($1,%massop.cnt,r)
 if (%massop.nick == $null) {
  if (%massop.nicks != $null) { .mode $1 +ooo %massop.nicks }
  unset %massop.*
  halt
  }
 set %massop.nicks %massop.nicks %massop.nick
 if ($numtok(%massop.nicks,32) == 3) && ($me isop $1) {
 .mode $1 +ooo %massop.nicks |
 unset %massop.nicks |
 goto loop
 }
goto loop
}


IP Scan

Questo script e' leggermente piu' complesso dei precedenti: il suo scopo e' quello di fare una ricerca di un IP (o di una serie di IP) in uno o piu' canali e viene utilizzato se/quando un firewall (ad esempio) individua qualche pacchetto pervenuto alla vostra macchina.
ATTENZIONE: questo script utilizza i raw quindi, se lo utilizzate con un altro script, dovete controllare che i raws utilizzati non entrino in conflitto con gli altri ulteriori raws.
La sintassi e': /ipscan [#canale]
Come al solito, se specificate un canale lo script effettuera' la ricerca limitando il raggio di azione a QUEL canale, se non ne viene specificato uno, lo script cerchera' l'ip su tutti i canali in cui vi trovate.
Il suo funzionamento e' molto semplice: ipscan si occupa di ricercare una stringa in una lista di ip.
Facciamo un esempio.
Il mio ICMPWatch mi dice che un tizio mi sta nukando.
Il suo ip e' 212.216.12.21.
A questo punto vi conviene fare due ricerche.
La prima e' sull'ìp completo, ossia 212.216.12.21.
La seconda e' la ricerca del suo DNS.
Scrivete /dns 212.216.12.21 e il mIRC vi dira' che l'ip corrisponde all'host a-vg2-22.tin.it.
Ora non vi resta che fare la ricerca utilizzando l'host.
Lo script funziona anche con parti di ip, quindi potreste anche fare una ricerca utilizzando come criterio a-vg.
In questo caso lo script vi dara' la lista di tutti quelli che hanno la stringa a-vg nel loro host.
Eccovi il listato.

alias ipscan {
 if ($chan(0) == 0) { echo -a Non sei su nessun canale... | halt }
 if ($1 != $null) && ($1 !ischan) {
  echo -a $1 non e' un nome di canale valido... |
  halt
 }
 set %ips.found 0
 set %ips.yn $?!="Aggiornare IAL prima di proseguire?"
 if (%ips.yn == $true) { .ial on | goto aggial }
 if (%ips.yn == $false) { goto begin }
 :aggial
 inc %ips.cnt
 if ($chan(%ips.cnt) == $null) { goto begin }
 .who $chan(%ips.cnt)
 goto aggial
 :begin
 set %ips.trigger $?="Immetti un criterio di ricerca... (ex. a-to)"
 :loop
 inc %ips.cnt
 if ($ial(*,%ips.cnt) == $null) {
  echo -a Users trovati secondo il criterio %ips.trigger $+ : %ips.found
  unset %ips.*
  halt
 }
 set %ips.ial $ial(*,%ips.cnt).host
 if (%ips.trigger isin %ips.ial) { goto ricerca }
 goto loop
 :ricerca
 inc %ips.chan
 if ($chan(%ips.chan) == $null) { goto loop }
 if ($1 == $null) {
  inc %ips.found
  echo -a Trovato $ial(*,%ips.cnt).nick ( $+ $ial(*,%ips.cnt).addr $+ ) su   $chan(%ips.chan)
  goto ricerca
 }
 if ($ial(*,%ips.cnt).nick ison $1) {
  inc %ips.found
  echo -a Trovato $ial(*,%ips.cnt).nick ( $+ $ial(*,%ips.cnt).addr $+ ) su $1 $+ ...
  goto ricerca
 }
 goto loop
}

raw 352:*: return
raw 315:*: echo -a Aggiornata IAL di $2 | return


Clear Ban List

Questo script e' sicuramente un passo avanti rispetto alla versione che possiamo trovare sul 7th sphere.
Le differenze sono diverse ma ci sono anche punti in comune: possiamo dire che la differenza sostanziale sta nell'utilizzo di comparazioni matematiche sui multipli del numero 3 (che e' il limite dei ban sbannabili su reti IRCnet).
Al solito la sintassi e' identica agli script precedenti.
Buon divertimento :o*

alias cblist {alias cblist {
 if ($1 == $null) {
  if ($active == $null) {
  echo -a Immettere un nome di canale o scrivere il comando nella finestra di   un canale...
  halt
  }
  else { set %cblist.chan $active | goto begin }
 }
 set %cblist.chan $1
 :begin
 .enable #banlist
 .mode # +b
}

#banlist on
raw 367:*: { inc %cblist.cnt | set %cblist. $+ %cblist.cnt $3- }
raw 368:*: {
 :loop
 inc %cblist.cnt2
 if (%cblist.cnt2 > %cblist.cnt) {
  echo -a mode %cblist.chan -bbb %cblist.ban
  echo -a Operazione terminata
  unset %cblist.*
  .disable #banlist
  halt
 }
 set %cblist.ban %cblist.ban %cblist. [ $+ [ %cblist.cnt2 ] ]
 if (%cblist.cnt2 < 3) { goto loop }
 if (%cblist.cnt2 // 3) {
  echo -a Passaggio... mode %cblist.chan -bbb %cblist.ban
  unset %cblist.ban
  goto loop
 }
 goto loop
}
#banlist end


Unzipper 4 warez

Questo script l'ho fatto pensando a tutti quelli che si scaricano 200 zip da un sito warez e che poi passano il pomeriggio a rincoglionirsi con il winzip :o(
Che fa sto script?
Provatelo e godrete di + quando giungera' l'ora di dezzippare :oD
Piccola nota: dovete avere il pkunzip.exe da qualche parte :o...

alias unzip {
 if (%pkunzip.unit == $null) { set %pkunzip.unit $sdir="Directory warez?" }
 if (%pkunzip.file == $null) { set %pkunzip.file $file="Directory e filename pkunzip.exe?" *.* }
 set %unzip.dir $sdir="Directory contenente files .zip?" %pkunzip.unit
 if ($findfile(%unzip.dir,*.zip,0) == 0) || ($findfile(%unzip.dir,*.zip,0) == $null) { echo -a Nessun .zip trovato... | unset %unzip.* | halt }
 set %unzip.subdir c:\ $+ $rand(A,Z) $+ $rand(a,z) $+ $rand(0,9) $+ $rand(A,Z) $+ $rand(a,z)
 echo -a Estrazione files prossima...
 echo -a Program: %pkunzip.file
 echo -a Directory: %unzip.dir
 echo -a Zips: $findfile(%unzip.dir,*.zip,0) file(s) trovati
 echo -a Destinazione: %unzip.subdir
 :loop
 inc %unzip.cnt
 set %unzip.file $findfile(%unzip.dir,*.zip,%unzip.cnt)
 if (%unzip.file == $null) { echo -a Operazione terminata... | unset %unzip.* | halt }
 set %unzip.continue $?!="Continuare con l'estrazione?"
 if (%unzip.continue == $false) { echo -a Operazione annullata... | unset %unzip.* | halt }
 else { run -n %pkunzip.file -d -e -o %unzip.file %unzip.subdir }
 goto loop
}


IP Extractor 4 Broadcast

Sto script qua l'ho fatto per estrarre gli ip da un bel txt pieeeeeeeno pieno di ip (appunto) da broadcast...
E' importante notare il secondo alias (alias isip) che puo' sempre tornarvi utile :o*

alias getip {
 set %getip.file $file="File di estrazione..." *.*
 write -c broadcast.txt
 echo -a Estrazione IP da Broadcast... File: $nopath(%getip.file) $+ ...
 :loop
 inc %getip.cnt
 set %getip.line $read -nl $+ %getip.cnt %getip.file
 if (%getip.line == $null) {
  echo -a Operazione terminata... Trovati: 0 $+ %getip.found
  unset %getip.* | halt
 }
 :cerca
 inc %getip.ntok
 set %getip.chk $gettok(%getip.line,%getip.ntok,32)
 if (%getip.chk == $null) { unset %getip.ntok | goto loop }
 if ($isip(%getip.chk) == si) { write -il1 broadcast.txt %getip.chk | inc %getip.found }
 goto cerca
 }

alias isip {
 if ($numtok($1,46) != 4) return no
 if ($gettok($1,1,46) !isnum) || ($gettok($1,1,46) < 0) || ($gettok($1,1,46) > 255) return no
 if ($gettok($1,2,46) !isnum) || ($gettok($1,2,46) < 0) || ($gettok($1,2,46) > 255) return no
 if ($gettok($1,3,46) !isnum) || ($gettok($1,3,46) < 0) || ($gettok($1,3,46) > 255) return no
 if ($gettok($1,4,46) !isnum) return no
 if ($gettok($1,4,46) != 0) { if ($gettok($1,4,46) == 255) return si | else return no }
 if ($gettok($1,4,46) != 255) { if ($gettok($1,4,46) == 0) return si | else return no }
}


IP Extractor 4 Broadcast (mejo)

Qual'era il problema dello script precedente?
Zzo ne so io >:oO
Pero' questo va mejo perche' ce sta un loop timerizzato che funge da pausa.
Anche questo vi puo' tornar utile prima o poi o forse molto prima del poi <:o?

alias pause {
 inc %puli.cnt
 set %puli.ip $read -n1 %puli.file
 if (%puli.ip == $null) && (%puli.mmm > 10) {
  echo -s finito
  beep | beep | beep
  .timerpuli off | unset %puli*
  halt
 }
 if (%puli.ip == $null) && (%puli.mmm < 10) { inc %puli.mmm | halt }
 if (100 // %puli.cnt) { echo -a Finiti i primi %puli.cnt }
 write -i c:\documenti\listaip.txt $gettok(%puli.ip,1,9)
 write -dl1 c:\documenti\order_by_ip.txt
 halt
}

alias pulisci {
 set %puli.file c:\documenti\order_by_ip.txt
 .timerpuli -m 0 40 pause
}


Enfroce ban

Se qualcuno banna un user voi lo kickate in automatico semplice no?

on *:BAN:#: {
 if ($me !isop #) { return }
 %enforce.cnt = 0
 if ($banmask iswm $address($me,5)) { unset %enforce.* | return }
 :loop
 inc %enforce.cnt
 if ($nick(#,%enforce.cnt) == $null) { unset %enforce.* | return }
 if ($banmask iswm $address($nick(#,%enforce.cnt),5)) {
  kick # $nick(#,%enforce.cnt) Enforce...  bannato da $nick
 }
 goto loop
}


Gestione controllo cloni

Se entra un clone TRACK lo script ve lo dice :o... ullalla' ma che fikata!

on *:JOIN:#: {
 if ($nick == $me) { return }
 set %cloni.nick $address($nick,2)
 :loop
 inc %cloni.cnt
 if ($nick(#,%cloni.cnt,2) == $null) { goto end }
 if ($nick(#,%cloni.cnt,2) == $nick) { goto loop }
 set %cloni.chk $address($nick(#,%cloni.cnt),2)
 if (%cloni.chk == %cloni.nick) { set %cloni.res %cloni.res -> $nick(#,%cloni.cnt) }
 goto loop
 :end
 if (%cloni.res != $null) {
  echo -a Cloni... $nick ( $+ $remove($address($nick,2),*!*@) $+ ) %cloni.res
 }
 unset %cloni.*
 return
}


Gestione scansione cloni

Una utility che serve a controllare se e quanti cloni ci sono su un determinato canale
Simpaticzik, da? :oD

alias cloni {
 unset %cloni.*
 if ($1 !ischan) && ($active !ischan) {
  echo -a Immettere un nome di canale o scrivere il comando nella finestra di un canale...
  halt
 }
 if ($1 != $null) { set %cloni.chan $1 }
 if ($active ischan) { set %cloni.chan $active }
 set %cloni.yon $?!="Si consiglia di aggiornare la IAL... Procedere?"
 if (%cloni.yon == $true) { who %cloni.chan | goto ial }
 else { goto plop }
 :ial
 set %cloni.yon $?!="Procedere? (attendere che venga aggiornata la IAL)"
 goto plop
 :plop
 write -c cloni.txt
 :lista
 inc %cloni.cnt
 set %cloni.nick $nick(%cloni.chan,%cloni.cnt)
 if (%cloni.nick == $null) { unset %cloni.cnt | goto controllo }
 write -i cloni.txt $address(%cloni.nick,5)
 goto lista

 :primo
 inc %cloni.totvar
 set %cloni.line $read -nl1 cloni.txt
 if (%cloni.line == $null) { .remove cloni.txt | goto end }
 write -dl1 cloni.txt
 set %clooni.nick $gettok(%cloni.line,1,33)
 set %clooni.host $gettok(%cloni.line,2,64)
 echo -a Controllo %clooni.nick - %clooni.hoost

 :controllo
 inc %cloni.cnt
 set %cloni.line $read -nl $+ %cloni.cnt cloni.txt
 if (%cloni.line == $null) {
 if (%cloni. [ $+ [ %cloni.totvar ] ] == $null) { dec %cloni.totvar }
 else {
  set %cloni. $+ %cloni.totvar %cloni.nick ( $+ %cloni.host $+ ) %cloni. [ $+ [ %cloni.totvar ] ]
 }
 goto primo
 }
 echo -a cloni %cloni.host
 if ($gettok(%clooni.line,2,64) != %clooni.host) { goto controllo }
 else {
  write -dl $+ %cloni.cnt cloni.txt
  dec %cloni.cnt
  if (%clooni.nick isin %cloni.totvar) {
   set %cloni. $+ %cloni.totvar %cloni. $+ %cloni.totvar ->   $gettok(%cloni.line,1,64)
  }
 }
 :end
 unset %cloni.*
}


Gestione resync canale

Semplicemente resynca un canale... o ci prova :o((

alias resync {
 if (%resync.cnt != $null) { goto loop }
 if ($1 !ischan) || ($me !isop $1) || ($me !isop $active) && ($active !ischan) {
  echo -a Immettere un nome di canale o scrivere il comando nella finestra di un canale...
  halt
 }
 if ($1 != $null) { set %resync.chan $1 }
 if ($active ischan) { set %resync.chan $active }
 set %resync.ops $nick(%resync.chan,0,o)
 :loop
 inc %resync.cnt
 set %resync.nick $nick(%resync.chan,%resync.cnt,o)
 if (%resync.nick == $null) {
  unset %resync.*
  echo -a Operazione terminata con successo...
  halt
 }
 if (%resync.nick == $me) { goto loop }
 mode %resync.chan -o %resync.nick
 mode %resync.chan +o %resync.nick
}

on *:OP:%resync.chan: {
 if ($me isop %resync.chan) { unset %resync.nick | resync }
 else { unset %resync.* | echo -a Operazione incompleta... | halt }
}


DCC Stat

Questo scriptino serve a fornire un report delle attivita' DCC in corso.
Sta sberla di script + qualche alias potrebbe sempre buttarvi giu' il morale :o... per quello ho messo sto script >:o)

alias ds {
 if ($get(0) != 0) || ($get(0) != 0) { echo   | goto begin }
 :begin
 if ($get(0) != 0) { goto get }
 if ($send(0) != 0) { goto send }
 else { echo -a Nessuna DCC attiva... | goto end }
 :get
 inc %ds.cnt
 if ($len(%ds.cnt) < 2) { set %ds.cnt 0 $+ %ds.cnt }
 if ($get(%ds.cnt) == $null) {
  if ($send(0) == 0) goto end
  else { unset %ds.* | goto send }
 }
 echo -a Get $chr(35) $+ %ds.cnt - Nick: $get(%ds.cnt) - File:  $left($get(%ds.cnt).file,15) - Dim: $mb($get(%ds.cnt).size) - Spd:  $mb($get(%ds.cnt).cps) $+ /s - Progs: $get(%ds.cnt).pc $+ $chr(37) - Restante:  $rget(%ds.cnt)
 goto get
 :send
 inc %ds.cnt
 if ($len(%ds.cnt) < 2) { set %ds.cnt 0 $+ %ds.cnt }
 if ($send(%ds.cnt) == $null) { unset %ds.* | goto end }
 if ($send(%ds.cnt).status == waiting) {
  echo -a Send $chr(35) $+ %ds.cnt - Nick: $send(%ds.cnt) - File: $send(%ds.cnt).file - Dim: $mb($send(%ds.cnt).size) - Status: In attesa di connessione...
  goto send
 }
 echo -a Send $chr(35) $+ %ds.cnt - Nick: $send(%ds.cnt) - File: $send(%ds.cnt).file - Dim: $mb($send(%ds.cnt).size) - Speed: $mb($send(%ds.cnt).cps) $+ /s - Progresso: $send(%ds.cnt).pc $+ $chr(37) - Restante: $rsend(%ds.cnt)
 goto send
 :end
 unset %ds.*
 halt
}

alias mb {
 if ($round($calc($1 / 1048576),2) < 1) { return $round($calc($1 / 1024),2) Kb }
 else return $round($calc($1 / 1048576),2) Mb
}

alias rget {
 set %ds.rest $calc($get($1).size - $get($1).rcvd)
 set %ds.sec $calc(%ds.rest / $get($1).cps)
 return $ndur(%ds.sec)
}

alias rsend {
 set %ds.rest $calc($send($1).size - $send($1).sent)
 set %ds.sec $calc(%ds.rest / $send($1).cps)
 return $ndur(%ds.sec)
}

alias ndur {
 if ($1 > 86399) { return Piu' di un giorno }
 if ($1 == 86400) { return Un giorno }
 if ($1 > 3600) && ($1 < 86400) {
  set %ds.ore $int($calc($1 / 3600))
  set %ds.min $int($calc(($1 - (%ds.ore * 3600)) / 60))
  set %ds.sec $int($calc($1 - (%ds.ore * 3600) - (%ds.min * 60)))
  goto end
 }
 if ($1 == 3600) { return 01:00:00 }
 if ($1 > 69) && ($1 < 3600) {
  set %ds.ore 00
  set %ds.min $int($calc($1 / 60))
  set %ds.sec $int($calc($1 - (%ds.min * 60)))
  goto end
 }
 if ($1 == 60) { return 00:01:00 }
 if ($1 < 60) {
  set %ds.ore 00
  set %ds.min 00
  set %ds.sec $int($1)
  goto end
 }
 :end
 if ($len(%ds.ore) < 2) { set %ds.ore 0 $+ %ds.ore }
 if ($len(%ds.min) < 2) { set %ds.min 0 $+ %ds.min }
 if ($len(%ds.sec) < 2) { set %ds.sec 0 $+ %ds.sec }
 return %ds.ore $+ : $+ %ds.min $+ : $+ %ds.sec
}


DCC Stat

La sveglia me la sono fatta per poter poi dire al capoufficio:
"GIURO CHE LA SVEGLIA NON HA SUONATO!!! NON E' COLPA MIA SE SONO ARRIVATO IN RITARDO!!!!!"
A volte la mia lameraggine mi spaventa <:o(

alias sveglia {
 if ($1 == $null) {
  if (%sveglia.ora != $null) {
   echo -a Sveglia attiva: %sveglia.ora - $left($nopath(%sveglia.file), $calc($len($nopath(%sveglia.file)) - 4))
  return
  }
  else { echo -a Errore di sintassi: /sveglia hh:mm | halt }
 }
 if ($1 == off) { .splay stop | unset %sveglia* | echo -a 'ngiornoooooo >:oD | halt }
 if ($1 == chk) { goto controlla }
 if (??:?? !iswm $1) { echo -a Errore di sintassi: /sveglia hh:mm | halt }
 :imposta
 set %sveglia.ora $1
 set %sveglia.file $file="File sveglia?" d:\music\*.mp3
 .timersveglia 0 10 sveglia chk
 echo -a Impostata la sveglietta alle ore $+ %sveglia.ora $+ :o* con $left($nopath(%sveglia.file), $calc($len($nopath(%sveglia.file)) - 4))
 halt
 :controlla
 if ($left($time,5) != %sveglia.ora) {
  if (%sveglia.fine != $null) {
   .timersveglia off
   echo -a Fottiti stronzo >:o $+ $chr(124)
   unset %sveglia*
   halt
  }
  return
 }
 .vol $calc($vol(mp3) + 1000)
 .splay -pq %sveglia.file
 echo -a SVEGLIATI CAZO >:oO!
 set %sveglia.fine okiz
 return
}

 

Prossimamente aggiungero' altri esempi.
Il mio sogno nel cassetto (ce l'ho da quando ero piccolo, ossia da un paio di anni) e' quello di piazzarvi uno script completo "smontato" in modo che tutti voi amanti della musica latina possiate un giorno giocare con il puzzle e montarvelo a casa vostra (un po' come i mobili dell'IKEA® che li monti e poi c'hanno sempre qualche problema di assestamento).